PhUSE Wiki

Oncology is one of the most prevalent indications for clinical trials today.  The data that is collected in support of these trials can be very complex, and the analyses performed are often specific to this indication.  One specific method of analyzing oncology data relates to clinical laboratory results.  While most clinical trials report laboratory results based on normal range criteria (is the result lower or higher than what is considered “normal”), oncology trials take that analysis to the next degree of specificity.  It is not enough to report where select laboratory results are too high or too low, it is important to report the degree of “lowness” or “highness.”   For example, if a patient’s hemoglobin results are 6.0 mmol/L, is that merely abnormal or is the patient near death?  In an indication such as oncology where patients are often expected to have abnormal laboratory results, it is important to know how abnormal the abnormal result actually is. 

In the United States, the National Cancer Institute publishes Common Terminology Criteria (formerly referred to as Common Toxicity Criteria) for Adverse Events to set a common standard for assigning severity grades to Adverse Events.  Events are graded on a scale of one to five with one meaning “mildly abnormal” and five meaning “death.”  Included within this list of standards are criteria for grading specific clinical laboratory results.  These criteria are often “disguised” as adverse events and careful review of all terms is needed to ensure that all laboratory tests that have criteria are graded.   A small excerpt of the file that is in the public domain and available for download as an Excel file is shown below (LLN = Lower Limit of Normal, ULN = Upper Limit of Normal).  Notice how the CTCAE terms do not always directly indicate the laboratory test to which the grades apply.

As with almost any task in SAS, there are multiple techniques available to assign CTC grades.  Part of what makes implementation difficult is the variety in the criteria themselves.  As mentioned above, some are based on fixed values, others are multiples of normal range criteria (which can change from study to study and even from patient to patient), and still others are a combination of the two.  The way the criteria vary make it impossible to simply enter values into a database and apply them as needed.  It is possible to write “fancy” code to implement these criteria, however there are several issues with using complicated code for this exercise. 

In many cases, complex code is more likely to be adversely affected by changes in the data and produce unreliable results.  If issues do arise, it is often more difficult to trace the source of the problem and subsequently to fix it.  This difficulty is compounded if the programmer who originally created the program is not available to diagnose and fix the problem.  In addition, complex code generally requires a senior-level resource to produce and maintain.  If the system developed is complex enough, even senior resources need to be trained on that system or take a significant amount of time to work through the logic of the programs for themselves.  While simple code is not as impressive, experience with several approaches has shown that the simple approach can be the most efficient way to apply CTC criteria.  One example of a simple approach to assigning CTC criteria for three tests (calcium, creatinine, and platelets) is presented below.   The key variables in the labs data set are as follows: lbtest contains the name of the laboratory test, lbstresn contains the laboratory result in standard units, lbstresu contains the name of the unit for lbstresn, lbstnrlo is the lower bound of the normal range and lbstnrhi is the upper bound of the normal range.  Lbstresn, lbstnrlo and lbstnrhi are all numeric variables reporting values in the same unit (as indicated by lbstresu).  Lbtoxgr is the name of the variable that will contain the CTC grade.

data labs ;

set inlib.labs ;

/**----- CALCIUM -----**/

if lbtest = "Calcium" then

do ;

  if nmiss(lbstnrhi, lbstnrlo) eq 0 then

  do ;

     if (lbstresn ge lbstnrlo) and (lbstresn le lbstnrhi) then lbtoxgr =0;

     else if (lbstresn ge 8)        and (lbstresn lt lbstnrlo) then lbtoxgr =1;

     else if (lbstresn gt lbstnrhi) and (lbstresn le 11.5)     then lbtoxgr =1;

  end ;

  else if lbstnrhi gt .z and lbstnrlo le .z then

  do ;

     if (lbstresn ge 8)        and (lbstresn lt lbstnrlo) then lbtoxgr =1;

     else if (lbstresn gt lbstnrhi) and (lbstresn le 11.5) then lbtoxgr =1;

  end ;

  else if lbstnrlo gt .z and lbstnrhi le .z then

  do ;

     if (lbstresn ge 8) and (lbstresn lt lbstnrlo) then lbtoxgr = 1 ;

  end ;

  if lbtoxgr eq . then

  do ;

     if (lbstresn ge 7)    and (lbstresn lt 8)    then lbtoxgr = 2 ;

     else if (lbstresn gt 11.5) and (lbstresn le 12.5) then lbtoxgr = 2 ;

     else if (lbstresn ge 6)    and (lbstresn lt 7)    then lbtoxgr = 3 ;

     else if (lbstresn gt 12.5) and (lbstresn le 13.5) then lbtoxgr = 3 ;

     else if                        (lbstresn lt 6)    then lbtoxgr = 4 ;

     else if (lbstresn gt 13.5)                        then lbtoxgr = 4 ;

  end ;

end ;

/*----- CREATININE -----*/

else if lbtest = "Creatinine" then

do ;

  if lbstnrhi gt .z then

  do ;

     if (lbstresn le lbstnrhi)       then lbtoxgr = 0 ;

     else if (lbstresn gt lbstnrhi)       and

             (lbstresn le (1.5*lbstnrhi)) then lbtoxgr = 1 ;

     else if (lbstresn gt (lbstnrhi*1.5)) and

             (lbstresn le (3*lbstnrhi))   then lbtoxgr = 2 ;

     else if (lbstresn gt (lbstnrhi*3))   and

             (lbstresn le (6*lbstnrhi))   then lbtoxgr = 3 ;

     else if (lbstresn gt (lbstnrhi*6))   then lbtoxgr = 4 ;

   end ;

end ;

/*----- PLATELETS -----*/

else if lbtest = "Platelet Count" then

do ;

  if lbstnrlo gt .z then

  do ;

     if (lbstresn ge lbstnrlo)                       then lbtoxgr = 0 ;

     else if (lbstresn ge 75)  and (lbstresn lt lbstnrlo) then lbtoxgr = 1 ;

     else if (lbstresn ge 50)  and (lbstresn lt 75)       then lbtoxgr = 2 ;

     else if (lbstresn ge 25)  and (lbstresn lt 50)       then lbtoxgr = 3 ;

     else if                       (lbstresn lt 25)       then lbtoxgr = 4 ;

  end ;

  else

  do ;

     if (lbstresn ge 50) and (lbstresn lt 75) then lbtoxgr = 2 ;

     else if (lbstresn ge 25) and (lbstresn lt 50) then lbtoxgr = 3 ;

     else if                      (lbstresn lt 25) then lbtoxgr = 4 ;

  end ;

end ;

run ;

Programs that implement the coding method above can get large.  However, it is important to note that CTC criteria do not change often.  Because of this, it is possible to reuse the code above across many studies with minimal changes.  It is also possible to facilitate the reuse of this code through the use of macros or simply creating a master program template that contains the code for all CTC criteria, then copy and paste from the master program into specific study programs.  While the simplicity of the code above may make it seem that applying CTC criteria is simple, there are many issues surrounding this process that can quickly make the code more complicated.

To successfully implement CTC grading, it is important to understand the issues surrounding practical implementation of these criteria.  One fundamental aspect of laboratory data is how it is collected – are samples sent to a single central laboratory or to various local laboratories for analysis?  Is the data provided electronically by a research laboratory or are the results entered onto the study Case Report Form (CRF)?  The answers to these questions can affect the unit of measure in which the data are reported (all tests reported in a single unit or in many different units).  It can also affect the normal ranges for each test – whether there is one standard or, if multiple laboratories are used, different standards for each laboratory.  All results and normal range criteria must be in the same unit for each test before attempting to apply CTC criteria. 

It is standard practice for all laboratory results to be reported in or converted into a standard unit, typically Standard International (SI) or conventional units (US).  For the purposes of this paper, it is assumed that all laboratory results and normal reference ranges have been converted into one of these standards and that all numeric variables with names beginning LBST contain data in the same unit.  If you want your CTC code to be robust enough to handle either type of unit, you can add the highlighted code below and use the new variables in the criteria logic. 

data labs;

   set inlib.labs ;

   if lbtest = "Calcium" then

   do ;

      ** CALCIUM CTC RANGE IN MG/DL: IF STANDARD UNIT is MMOL/L THEN CONVERT **;

           if upcase(trim(lbstresu)) = 'MG/DL'  then ctcx = 1 ;

      else if upcase(trim(lbstresu)) = 'MMOL/L' then ctcx = 4.008 ;

      else if compress(lbstresu) ne '' then

           put '>>> INVALID UNIT FOR CALCIUM CTC GRADING: ' LBSTRESU ;

      if ctcx ne . then

      do ;

         ctcval = lbstresn*ctcx ;

         if lbstnrlo ne . then ctclo = lbstnrlo*ctcx ;

         if lbstnrhi ne . then ctchi = lbstnrhi*ctcx ;

         if nmiss(ctchi, ctclo) eq 0 then

         do ;

                 if (ctcval ge ctclo) and (ctcval le ctchi) then lbtoxgr = 0 ;

            else if (ctcval ge 8)     and (ctcval lt ctclo) then lbtoxgr = 1 ;

            else if (ctcval gt ctchi) and (ctcval le 11.5)  then lbtoxgr = 1 ;

         end ;

         else if ctchi gt .z and ctclo le .z then

         do ;

                 if (ctcval ge 8)     and (ctcval lt ctclo) then lbtoxgr = 1 ;

            else if (ctcval gt ctchi) and (ctcval le 11.5)  then lbtoxgr = 1 ;

         end ;

         else if ctclo gt .z and ctchi le .z then

         do ;

            if (ctcval ge 8) and (ctcval lt ctclo) then lbtoxgr = 1 ;

         end ;

         if lbtoxgr eq . then

         do ;

                 if (ctcval ge 7)    and (ctcval lt 8)    then lbtoxgr = 2 ;

            else if (ctcval gt 11.5) and (ctcval le 12.5) then lbtoxgr = 2 ;

            else if (ctcval ge 6)    and (ctcval lt 7)    then lbtoxgr = 3 ;

            else if (ctcval gt 12.5) and (ctcval le 13.5) then lbtoxgr = 3 ;

            else if                      (ctcval lt 6)    then lbtoxgr = 4 ;

            else if (ctcval gt 13.5)                      then lbtoxgr = 4 ;

         end ;

      end ;

   end ;

   … code continues …

run ;

With the code above, if laboratory data is reported in an unexpected unit, the SAS program log will display a message noting the name of the test and the invalid unit (e.g. >>> INVALID UNIT FOR CALCIUM CTC GRADING: G/DL).

When laboratory results are provided by local laboratories and collected on CRF pages, it is not unusual for some records to be missing normal range criteria.  Many CTC criteria use the lower (LLN) and/or upper (ULN) bounds of the normal range and this missing information may prevent CTC criteria from being applied.  Based on the number of records with missing normal ranges, default normal ranges may need to be used in cases where the ranges from the local laboratory are not available. See the code below for one way to modify the basic code to address this issue.

if lbtest = "Calcium" then

   do ;

      ** CALCIUM CTC RANGE IN MG/DL: IF STANDARD UNIT is MMOL/L THEN CONVERT **;

           if upcase(trim(lbstresu)) = 'MG/DL'  then ctcx = 1 ;

      else if upcase(trim(lbstresu)) = 'MMOL/L' then ctcx = 4.008 ;

      else if compress(lbstresu) ne '' then

           put '>>> INVALID UNIT FOR CALCIUM CTC GRADING: ' LBSTRESU ;

      if ctcx ne . then

      do ;

         ctcval = round(lbstresn*ctcx,.01) ;

         if lbstnrlo ne . then ctclo = round(lbstnrlo*ctcx,.01) ;

                          else ctclo = 8.5 ;             ** DEFAULT LOW RANGE **;

         if lbstnrhi ne . then ctchi = round(lbstnrhi*ctcx,.01) ;

                          else ctchi = 11.5 ;            ** DEFAULT HIGH RANGE **;

              if (ctcval ge ctclo) and (ctcval le ctchi) then lbtoxgr = 0 ;

         else if (ctcval ge 8)     and (ctcval lt ctclo) then lbtoxgr = 1 ;

         else if (ctcval gt ctchi) and (ctcval le 11.5)  then lbtoxgr = 1 ;

         … code continues …

When converting results from one unit to another, the new result will often have many more decimal places than the original.  It is rare for summary reports to show results with more than three decimals, often two decimals is the maximum shown.  It is important to decide if converted results should be rounded before or after applying CTC criteria as it can affect how the data are reported.  Consider the calcium data below.

                 --------- NOT ROUNDED ----------  ---------- ROUNDED -----------

subjid visitnum  ctcval   ctclo    ctchi  lbtoxgr  ctcvalr ctclor ctchir lbtoxgrr

00003     101    9.8597  8.41683  10.2204    0       9.86   8.42   10.22     0

00003     103    9.3387  8.41683  10.2204    0       9.34   8.42   10.22     0

00003     108   11.5016  8.41683  10.2204    2      11.50   8.42   10.22     1

00003     109   11.4964  8.41683  10.2204    1      11.50   8.42   10.22     1

00003     110    9.7395  8.10000  10.4000    0       9.74   8.10   10.40     0

00003     114    9.6593  8.41683  10.2204    0       9.66   8.42   10.22     0

00003     142    9.7796  8.41683  10.2204    0       9.78   8.42   10.22     0

For calcium, the range of values for grade one is 10.22 mg/dL (ULN) to 11.5 (fixed) and rounding the data prior to applying the criteria results in a different grade being assigned.  In the example above, it may look suspicious if grades were assigned using the unrounded data but listings display the rounded calcium result as 11.50 with a CTC grade of two on one record but grade one on another.  Results like this will likely raise questions regarding the accuracy of grading unless reports indicate that grades were assigned using a higher level of precision than shown.  Either approach is acceptable, but should be planned for and explained at the beginning of a project.

One particularly tricky issue pertains to CTC criteria which mix normal ranges with fixed values.  In these cases, it is possible that the normal range values equal or overlap the CTC criteria bounds.  For example, the bounds for platelet grade one are >= 75 x 10³/UL to LLN – what if the LLN for a particular laboratory is 75?  That would make the bounds for grade one 75 to 75 and the bounds for grade two 50 to 75.  If a patient has a lab result of 75, that result may be coded to either grade one or grade two if the method of assigning grades does not take this into account.   The simple code presented above would correctly assign a grade one in this scenario.

In addition to normal ranges equaling CTC bounds, it is also possible for normal ranges to overlap CTC bounds.  Consider if the LLN for a calcium result is 7.89 mg/dL.  This would make the boundary for CTC grade one be >= 8 to <7.89 while the boundary for grade two is 7 to <8.  In this case, the LLN is actually within the grade two range boundaries.  In this case, the decision needs to be made whether CTC grade criteria override laboratory normal ranges or vice versa.   If normal ranges are allowed to take precedence, the following results are produced:

subjid    lbtest     visitnum     ctcval     ctclo      ctchi     lbtoxgr

00004     Calcium       16       11.1994    7.89402    10.4208       1   

00004     Calcium       17        8.6573    7.89402    10.4208       0  

00004     Calcium       21        9.2184    7.89402    10.4208       0  

00004     Calcium       22        7.9325    7.89402    10.4208       0   

00004     Calcium       23        8.9780    7.89402    10.4208       0 

To override normal ranges, the following adjustment can be made to the standard code:

   if lbtest = "Calcium" then

   do ;

      ** CALCIUM CTC RANGE IN MG/DL: IF STANDARD UNIT is MMOL/L THEN CONVERT **;

           if upcase(trim(lbstresu)) = 'MG/DL'  then ctcx = 1 ;

      else if upcase(trim(lbstresu)) = 'MMOL/L' then ctcx = 4.008 ;

      else if compress(lbstresu) ne '' then

           put '>>> INVALID UNIT FOR CALCIUM CTC GRADING: ' LBSTRESU ;

      if ctcx ne . then

      do ;

         ctcval = lbstresn*ctcx ;

         if lbstnrlo ne . then ctclo = lbstnrlo*ctcx ;

         if lbstnrhi ne . then ctchi = lbstnrhi*ctcx ;

          ** MAKE SURE NORMAL RANGES DO NOT OVERLAP CTC CRITERIA –

            CTC TAKES PRECEDENCE **;

         if ctclo lt 8    then ctclo = 8 ;

         if ctchi gt 11.5 then ctchi = 11.5 ;

         if nmiss(ctchi, ctclo) eq 0 then

         do ;

                 if (ctcval ge ctclo) and (ctcval le ctchi) then lbtoxgr = 0 ;

            else if (ctcval ge 8)     and (ctcval lt ctclo) then lbtoxgr = 1 ;

            else if (ctcval gt ctchi) and (ctcval le 11.5)  then lbtoxgr = 1 ;

         end ;

         etc.

With the code above in place, the same data yields a very different result.

subjid    lbtest     visitnum     ctcval    ctclo     ctchi     lbtoxgr

00004     Calcium       16       11.1994      8      10.4208       1  

00004     Calcium       17        8.6573      8      10.4208       0  

00004     Calcium       21        9.2184      8      10.4208       0  

00004     Calcium       22        7.9325      8      10.4208       2   

00004     Calcium       23        8.9780      8      10.4208       0  

There are several laboratory tests that have separate CTC grade criteria for both ends of the normal range (one set of grades for low values and another for high values).  These “bi-directional” tests include calcium, sodium, glucose, magnesium and potassium.  While assigning grades to these tests is not necessarily an issue, reporting them can be challenging.  Technically, CTC grades do not indicate the direction of the abnormality – a CTC grade of two for calcium does not indicate whether the abnormality is above or below the normal range.  However, when reporting these grades in summary tables, programmers are often required to indicate whether the result is “grade two, low” or “grade two, high.”  For these tests, it may be desirable to add a variable to indicate whether the CTC grade refers to a value that is above or below the normal range.  Because change from baseline statistics are often presented, one solution to address these bi-directional tests is to create a second variable where grades above normal are reported as positive values while grades below normal are negative.  The highlighted code below can be added to produce the numeric variable lbtoxgrs which would contain the CTC grade with a negative sign to indicate the grades below normal.

   if lbtest = "Calcium" then

   do ;

      … code …

         if lbtoxgr eq . then

         do ;

                 if (ctcval ge 7)    and (ctcval lt 8)    then lbtoxgr = 2 ;

            else if (ctcval gt 11.5) and (ctcval le 12.5) then lbtoxgr = 2 ;

            else if (ctcval ge 6)    and (ctcval lt 7)    then lbtoxgr = 3 ;

            else if (ctcval gt 12.5) and (ctcval le 13.5) then lbtoxgr = 3 ;

            else if                      (ctcval lt 6)    then lbtoxgr = 4 ;

            else if (ctcval gt 13.5)                      then lbtoxgr = 4 ;

         end ;

         if ctcval lt ctclo then lbtoxgrs = 0-lbtoxgr ;

                            else lbtoxgrs = lbtoxgr ;

      end ;

   end ;

Continuing from the previous example, the result of executing the code above is listed below.

subjid    lbtest     visitnum     ctcval    ctclo     ctchi     lbtoxgr    lbtoxgrs

00004     Calcium       16       11.1994      8      10.4208       1           1   00004     Calcium       17        8.6573      8      10.4208       0           0   00004     Calcium       21        9.2184      8      10.4208       0           0   00004     Calcium       22        7.9325      8      10.4208       2          -2   00004     Calcium       23        8.9780      8      10.4208       0           0  

By creating a variable with the direction of the abnormality included, it is possible to present the CTC grades in a way that indicates the direction of the abnormality, as well as calculate change from baseline appropriately. 

National Cancer Institute, Common Terminology Criteria for Adverse Events (CTCAE) v4.0